local images = import "values/images.jsonnet";
local url = import "values/url.jsonnet";
local prompts = import "prompts/mixtral.jsonnet";
local models = import "parameters/embeddings-fastembed.jsonnet";

{

    "fastembed-models":: models,

    "embeddings-models" +:: $["fastembed-models"],

    embeddings +: {

        create:: function(engine)

            local concurrency = self.concurrency;

            local container =
                engine.container("embeddings")
                    .with_image(images.trustgraph_flow)
                    .with_command([
                        "embeddings-fastembed",
                    ] + $["pub-sub-args"] + [
                        "--concurrency",
                        std.toString(concurrency),
                        "--log-level",
                        $["log-level"],
                    ])
                    .with_limits("2.0", "600M")
                    .with_reservations("1.0", "600M");

            local containerSet = engine.containers(
                "embeddings", [ container ]
            );

            local service =
                engine.internalService(containerSet)
                .with_port(8000, 8000, "metrics");

            engine.resources([
                containerSet,
                service,
            ])

    },

}